$ontext
Solve this model "WAREHOUSE" using GAMS.
Have a look at the listing file (your filename.lst) and find the solution
of this optimization problem and a lot more information (please notice
the menu items SolVAR and Display at the menu on the left side of the
listing ).
In the listing, at the "Display" part, you'll find the
used values for w, d, h, at SolVAR the solution of the problem.
If you don't use GAMS IDE (in case of Mac OS or Linux platforms) you will
find the solution towards the end of the listing file following
"Solver Statistics".
$offtext
SCALARS
u gap between roof and top of the racks /0.7/
h height of pallet /2/
w width of pallet /2.5/
d depth of pallet /5/
c1 cost of a crane /12000/
c2 cost of a steel rack /100/
cW cost of wall per square meter /40/
cF cost of floor per square meter /30/
cC cost of floor (corridor) per square meter /90/
cR cost of roof /200/;
INTEGER VARIABLES
n number of corridors
k number of racks side by side
m number of racks on top of each other;
n.lo = 1;
m.lo = 1;
k.lo = 1;
POSITIVE VARIABLES
t total height of the building
x length of the building
y width of the building
p number of pallets;
* You can add a comment line by adding a "*" at the first column
$eolcom #
* With "$eolcom #" you can write comments at the end of a comment line
t.lo = 6;
t.up = 22; # maximal allowed height of the building
p.lo = 2000;
VARIABLE
Z Total cost of new warehouse;
EQUATIONS
COST define objective funtion
pallet number of pallets
Height height of the warehouse
Width width of the warehouse
Length length of the warehouse;
COST.. Z =E= (n*c1)+(2*k*m*n*c2)+
((2*y+x)*t*cW)+
(x*y*(cR+cF))+
(n*k*(w+0.30)*(d+0.15)*3/2)*(cC-CF);
pallet.. p =E= 2*k*m*n;
Height.. t =G= m*(h+0.30)+u;
Length.. x =E= (2*(d+0.15)+(3*d/2))*n;
Width.. y =E= k*(w+0.30)+(w+0.30);
MODEL WAREHOUSE /ALL/ ;
OPTIONS MINLP = COUENNE;
SOLVE WAREHOUSE USING MINLP MINIMIZING Z ;
display h, w, d;